home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 2: CDPD 1 / Almathera Ten on Ten - Disc 2: CDPD 1.iso / protracker / pt-ciaplay.s < prev    next >
Text File  |  1995-03-15  |  25KB  |  1,311 lines
  1.         opt l-
  2.  
  3.  
  4. ;********************************************
  5. ;* ----- Protracker V1.1B Playroutine ----- *
  6. ;* Lars "Zap" Hamre/Amiga Freelancers 1991  *
  7. ;* Bekkeliveien 10, N-2010 STRØMMEN, Norway *
  8. ;********************************************
  9.  
  10. DMAWait = 1000 ; Set this as low as possible without losing low notes.
  11.  
  12. ; CIA Version 1:
  13. ; Call SetCIAInt to install the interrupt server. Then call mt_init
  14. ; to initialize the song. Playback starts when the mt_enable flag
  15. ; is set to a nonzero value. To end the song and turn off all voices,
  16. ; call mt_end. At last, call ResetCIAInt to remove the interrupt.
  17.  
  18. ; This playroutine is not very fast, optimized or well commented,
  19. ; but all the new commands in PT1.1 should work.
  20. ; If it's not good enough, you'll have to change it yourself.
  21. ; We'll try to write a faster routine soon...
  22.  
  23. ; Changes from V1.0C playroutine:
  24. ; - Vibrato depth changed to be compatible with Noisetracker 2.0.
  25. ;   You'll have to double all vib. depths on old PT modules.
  26. ; - Funk Repeat changed to Invert Loop.
  27. ; - Period set back earlier when stopping an effect.
  28.  
  29. ; You can use this routine to play a module. Just remove the semicolons.
  30. ; Exit by pressing both mousebuttons.
  31. ;
  32. main    BSR.S    SetCIAInt
  33.     BSR    mt_init
  34.     ST    mt_Enable
  35.     MOVE.L    4.W,A6
  36.     LEA    DOSname(PC),A1
  37.     MOVEQ    #0,D0
  38.     JSR    LVOOpenLibrary(A6)
  39.     TST.L    D0
  40.     BEQ.S    theend
  41.     MOVE.L    D0,A6
  42. wloop    MOVEQ    #10,D1
  43.     JSR    LVODelay(A6)
  44.    tst.b    0
  45.     BEq.S    wloop
  46.     MOVE.L    A6,A1
  47.     MOVE.L    4.W,A6
  48.     JSR    LVOCloseLibrary(A6)
  49. theend    BSR    mt_end
  50.     BSR    ResetCIAInt
  51.     RTS
  52.  
  53. DOSname    dc.b "dos.library",0
  54.  
  55. ;---- CIA Interrupt ----
  56.  
  57. AddICRVector    =   -6
  58. RemICRVector    =  -12
  59. LVOOpenResource    = -498
  60. LVOOpenLibrary     = -552
  61. LVOCloseLibrary    = -414
  62. LVODelay    = -198
  63.  
  64. ciatalo = $400
  65. ciatahi = $500
  66. ciatblo = $600
  67. ciatbhi = $700
  68. ciacra  = $E00
  69. ciacrb  = $F00
  70.  
  71. SetCIAInt
  72.     MOVEQ    #2,D6
  73.     LEA    $BFD000,A5
  74.     MOVE.B    #'b',CIAAname+3
  75. SetCIALoop
  76.     MOVEQ    #0,D0
  77.     LEA    CIAAname(PC),A1
  78.     MOVE.L    4.W,A6
  79.     JSR    LVOOpenResource(A6)
  80.     MOVE.L    D0,CIAAbase
  81.     BEQ    mt_Return
  82.  
  83.     LEA    GfxName(PC),A1
  84.     MOVEQ    #0,D0
  85.     JSR    LVOOpenLibrary(A6)
  86.     TST.L    D0
  87.     BEQ    ResetCIAInt
  88.     MOVE.L    D0,A1
  89.     MOVE.W    206(A1),D0    ; DisplayFlags
  90.     BTST    #2,D0        ; PAL?
  91.     BEQ.S    WasNTSC
  92.     MOVE.L    #1773447,D7 ; PAL
  93.     BRA.S    sciask
  94. WasNTSC    MOVE.L    #1789773,D7 ; NTSC
  95. sciask    MOVE.L    D7,TimerValue
  96.     DIVU    #125,D7 ; Default to normal 50 Hz timer
  97.     JSR    LVOCloseLibrary(A6)
  98.  
  99.     MOVE.L    CIAAbase(PC),A6
  100.     CMP.W    #2,D6
  101.     BEQ.S    TryTimerA
  102. TryTimerB
  103.     LEA    MusicIntServer(PC),A1
  104.     MOVEQ    #1,D0    ; Bit 1: Timer B
  105.     JSR    AddICRVector(A6)
  106.     MOVE.L    #1,TimerFlag
  107.     TST.L    D0
  108.     BNE.S    CIAError
  109.     MOVE.L    A5,CIAAaddr
  110.     MOVE.B    D7,ciatblo(A5)
  111.     LSR.W    #8,D7
  112.     MOVE.B    D7,ciatbhi(A5)
  113.     BSET    #0,ciacrb(A5)
  114.     RTS
  115.  
  116. TryTimerA
  117.     LEA    MusicIntServer(PC),A1
  118.     MOVEQ    #0,D0    ; Bit 0: Timer A
  119.     JSR    AddICRVector(A6)
  120.     CLR.L    TimerFlag
  121.     TST.L    D0
  122.     BNE.S    CIAError
  123.     MOVE.L    A5,CIAAaddr
  124.     MOVE.B    D7,ciatalo(A5)
  125.     LSR.W    #8,D7
  126.     MOVE.B    D7,ciatahi(A5)
  127.     BSET    #0,ciacra(A5)
  128.     RTS
  129.  
  130. CIAError
  131.     MOVE.B    #'a',CIAAname+3
  132.     LEA    $BFE001,A5
  133.     SUBQ.W    #1,D6
  134.     BNE    SetCIALoop
  135.     CLR.L    CIAAbase
  136.     RTS
  137.  
  138. ResetCIAInt
  139.     MOVE.L    CIAAbase(PC),D0
  140.     BEQ    mt_Return
  141.     CLR.L    CIAAbase
  142.     MOVE.L    D0,A6
  143.     MOVE.L    CIAAaddr(PC),A5
  144.     TST.L    TimerFlag
  145.     BEQ.S    ResTimerA
  146.  
  147.     BCLR    #0,ciacrb(A5)
  148.     MOVEQ    #1,D0
  149.     BRA.S    RemInt
  150.  
  151. ResTimerA
  152.     BCLR    #0,ciacra(A5)
  153.     MOVEQ    #0,D0
  154. RemInt    LEA    MusicIntServer(PC),A1
  155.     MOVEQ    #0,d0
  156.     JSR    RemICRVector(A6)
  157.     RTS
  158.  
  159. ;---- Tempo ----
  160.  
  161. SetTempo
  162.     MOVE.L    CIAAbase(PC),D2
  163.     BEQ    mt_Return
  164.     CMP.W    #32,D0
  165.     BHS.S    setemsk
  166.     MOVEQ    #32,D0
  167. setemsk    MOVE.W    D0,RealTempo
  168.     MOVE.L    TimerValue(PC),D2
  169.     DIVU    D0,D2
  170.     MOVE.L    CIAAaddr(PC),A4
  171.     MOVE.L    TimerFlag(PC),D0
  172.     BEQ.S    SetTemA
  173.     MOVE.B    D2,ciatblo(A4)
  174.     LSR.W    #8,D2
  175.     MOVE.B    D2,ciatbhi(A4)
  176.     RTS
  177.  
  178. SetTemA    MOVE.B    D2,ciatalo(A4)
  179.     LSR.W    #8,D2
  180.     MOVE.B    D2,ciatahi(A4)
  181.     RTS
  182.  
  183. RealTempo    dc.w 125
  184. CIAAaddr    dc.l 0
  185. CIAAname    dc.b "ciaa.resource",0
  186. CIAAbase    dc.l 0
  187. TimerFlag    dc.l 0
  188. TimerValue    dc.l 0
  189. GfxName        dc.b "graphics.library",0,0
  190.  
  191. MusicIntServer
  192.     dc.l 0,0
  193.     dc.b 2,5 ; type, priority
  194.     dc.l musintname
  195.     dc.l 0,mt_music
  196.  
  197. musintname    dc.b "Protracker MusicInt",0
  198.  
  199. ;---- Playroutine ----
  200.  
  201. n_note        EQU    0  ; W
  202. n_cmd        EQU    2  ; W
  203. n_cmdlo        EQU    3  ; B
  204. n_start        EQU    4  ; L
  205. n_length    EQU    8  ; W
  206. n_loopstart    EQU    10 ; L
  207. n_replen    EQU    14 ; W
  208. n_period    EQU    16 ; W
  209. n_finetune    EQU    18 ; B
  210. n_volume    EQU    19 ; B
  211. n_dmabit    EQU    20 ; W
  212. n_toneportdirec    EQU    22 ; B
  213. n_toneportspeed    EQU    23 ; B
  214. n_wantedperiod    EQU    24 ; W
  215. n_vibratocmd    EQU    26 ; B
  216. n_vibratopos    EQU    27 ; B
  217. n_tremolocmd    EQU    28 ; B
  218. n_tremolopos    EQU    29 ; B
  219. n_wavecontrol    EQU    30 ; B
  220. n_glissfunk    EQU    31 ; B
  221. n_sampleoffset    EQU    32 ; B
  222. n_pattpos    EQU    33 ; B
  223. n_loopcount    EQU    34 ; B
  224. n_funkoffset    EQU    35 ; B
  225. n_wavestart    EQU    36 ; L
  226. n_reallength    EQU    40 ; W
  227.  
  228. mt_init    LEA    mt_data,A0
  229.     MOVE.L    A0,mt_SongDataPtr
  230.     MOVE.L    A0,A1
  231.     LEA    952(A1),A1
  232.     MOVEQ    #127,D0
  233.     MOVEQ    #0,D1
  234. mtloop    MOVE.L    D1,D2
  235.     SUBQ.W    #1,D0
  236. mtloop2    MOVE.B    (A1)+,D1
  237.     CMP.B    D2,D1
  238.     BGT.S    mtloop
  239.     DBRA    D0,mtloop2
  240.     ADDQ.B    #1,D2
  241.             
  242.     LEA    mt_SampleStarts(PC),A1
  243.     ASL.L    #8,D2
  244.     ASL.L    #2,D2
  245.     ADD.L    #1084,D2
  246.     ADD.L    A0,D2
  247.     MOVE.L    D2,A2
  248.     MOVEQ    #30,D0
  249. mtloop3    CLR.L    (A2)
  250.     MOVE.L    A2,(A1)+
  251.     MOVEQ    #0,D1
  252.     MOVE.W    42(A0),D1
  253.     ASL.L    #1,D1
  254.     ADD.L    D1,A2
  255.     ADD.L    #30,A0
  256.     DBRA    D0,mtloop3
  257.  
  258.     OR.B    #2,$BFE001
  259.     MOVE.B    #6,mt_speed
  260.     CLR.B    mt_counter
  261.     CLR.B    mt_SongPos
  262.     CLR.W    mt_PatternPos
  263. mt_end    SF    mt_Enable
  264.     LEA    $DFF000,A0
  265.     CLR.W    $A8(A0)
  266.     CLR.W    $B8(A0)
  267.     CLR.W    $C8(A0)
  268.     CLR.W    $D8(A0)
  269.     MOVE.W    #$F,$DFF096
  270.     RTS
  271.  
  272. mt_music
  273.     MOVEM.L    D0-D4/A0-A6,-(SP)
  274.     TST.B    mt_Enable
  275.     BEQ    mt_exit
  276.     ADDQ.B    #1,mt_counter
  277.     MOVE.B    mt_counter(PC),D0
  278.     CMP.B    mt_speed(PC),D0
  279.     BLO.S    mt_NoNewNote
  280.     CLR.B    mt_counter
  281.     TST.B    mt_PattDelTime2
  282.     BEQ.S    mt_GetNewNote
  283.     BSR.S    mt_NoNewAllChannels
  284.     BRA    mt_dskip
  285.  
  286. mt_NoNewNote
  287.     BSR.S    mt_NoNewAllChannels
  288.     BRA    mt_NoNewPosYet
  289.  
  290. mt_NoNewAllChannels
  291.     LEA    $DFF0A0,A5
  292.     LEA    mt_chan1temp(PC),A6
  293.     BSR    mt_CheckEfx
  294.     LEA    $DFF0B0,A5
  295.     LEA    mt_chan2temp(PC),A6
  296.     BSR    mt_CheckEfx
  297.     LEA    $DFF0C0,A5
  298.     LEA    mt_chan3temp(PC),A6
  299.     BSR    mt_CheckEfx
  300.     LEA    $DFF0D0,A5
  301.     LEA    mt_chan4temp(PC),A6
  302.     BRA    mt_CheckEfx
  303.  
  304. mt_GetNewNote
  305.     MOVE.L    mt_SongDataPtr(PC),A0
  306.     LEA    12(A0),A3
  307.     LEA    952(A0),A2    ;pattpo
  308.     LEA    1084(A0),A0    ;patterndata
  309.     MOVEQ    #0,D0
  310.     MOVEQ    #0,D1
  311.     MOVE.B    mt_SongPos(PC),D0
  312.     MOVE.B    (A2,D0.W),D1
  313.     ASL.L    #8,D1
  314.     ASL.L    #2,D1
  315.     ADD.W    mt_PatternPos(PC),D1
  316.     CLR.W    mt_DMACONtemp
  317.  
  318.     LEA    $DFF0A0,A5
  319.     LEA    mt_chan1temp(PC),A6
  320.     BSR.S    mt_PlayVoice
  321.     LEA    $DFF0B0,A5
  322.     LEA    mt_chan2temp(PC),A6
  323.     BSR.S    mt_PlayVoice
  324.     LEA    $DFF0C0,A5
  325.     LEA    mt_chan3temp(PC),A6
  326.     BSR.S    mt_PlayVoice
  327.     LEA    $DFF0D0,A5
  328.     LEA    mt_chan4temp(PC),A6
  329.     BSR.S    mt_PlayVoice
  330.     BRA    mt_SetDMA
  331.  
  332. mt_PlayVoice
  333.     TST.L    (A6)
  334.     BNE.S    mt_plvskip
  335.     BSR    mt_PerNop
  336. mt_plvskip
  337.     MOVE.L    (A0,D1.L),(A6)
  338.     ADDQ.L    #4,D1
  339.     MOVEQ    #0,D2
  340.     MOVE.B    n_cmd(A6),D2
  341.     AND.B    #$F0,D2
  342.     LSR.B    #4,D2
  343.     MOVE.B    (A6),D0
  344.     AND.B    #$F0,D0
  345.     OR.B    D0,D2
  346.     TST.B    D2
  347.     BEQ    mt_SetRegs
  348.     MOVEQ    #0,D3
  349.     LEA    mt_SampleStarts(PC),A1
  350.     MOVE    D2,D4
  351.     SUBQ.L    #1,D2
  352.     ASL.L    #2,D2
  353.     MULU    #30,D4
  354.     MOVE.L    (A1,D2.L),n_start(A6)
  355.     MOVE.W    (A3,D4.L),n_length(A6)
  356.     MOVE.W    (A3,D4.L),n_reallength(A6)
  357.     MOVE.B    2(A3,D4.L),n_finetune(A6)
  358.     MOVE.B    3(A3,D4.L),n_volume(A6)
  359.     MOVE.W    4(A3,D4.L),D3 ; Get repeat
  360.     TST.W    D3
  361.     BEQ.S    mt_NoLoop
  362.     MOVE.L    n_start(A6),D2    ; Get start
  363.     ASL.W    #1,D3
  364.     ADD.L    D3,D2        ; Add repeat
  365.     MOVE.L    D2,n_loopstart(A6)
  366.     MOVE.L    D2,n_wavestart(A6)
  367.     MOVE.W    4(A3,D4.L),D0    ; Get repeat
  368.     ADD.W    6(A3,D4.L),D0    ; Add replen
  369.     MOVE.W    D0,n_length(A6)
  370.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  371.     MOVEQ    #0,D0
  372.     MOVE.B    n_volume(A6),D0
  373.     MOVE.W    D0,8(A5)    ; Set volume
  374.     BRA.S    mt_SetRegs
  375.  
  376. mt_NoLoop
  377.     MOVE.L    n_start(A6),D2
  378.     ADD.L    D3,D2
  379.     MOVE.L    D2,n_loopstart(A6)
  380.     MOVE.L    D2,n_wavestart(A6)
  381.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  382.     MOVEQ    #0,D0
  383.     MOVE.B    n_volume(A6),D0
  384.     MOVE.W    D0,8(A5)    ; Set volume
  385. mt_SetRegs
  386.     MOVE.W    (A6),D0
  387.     AND.W    #$0FFF,D0
  388.     BEQ    mt_CheckMoreEfx    ; If no note
  389.     MOVE.W    2(A6),D0
  390.     AND.W    #$0FF0,D0
  391.     CMP.W    #$0E50,D0
  392.     BEQ.S    mt_DoSetFineTune
  393.     MOVE.B    2(A6),D0
  394.     AND.B    #$0F,D0
  395.     CMP.B    #3,D0    ; TonePortamento
  396.     BEQ.S    mt_ChkTonePorta
  397.     CMP.B    #5,D0
  398.     BEQ.S    mt_ChkTonePorta
  399.     CMP.B    #9,D0    ; Sample Offset
  400.     BNE.S    mt_SetPeriod
  401.     BSR    mt_CheckMoreEfx
  402.     BRA.S    mt_SetPeriod
  403.  
  404. mt_DoSetFineTune
  405.     BSR    mt_SetFineTune
  406.     BRA.S    mt_SetPeriod
  407.  
  408. mt_ChkTonePorta
  409.     BSR    mt_SetTonePorta
  410.     BRA    mt_CheckMoreEfx
  411.  
  412. mt_SetPeriod
  413.     MOVEM.L    D0-D1/A0-A1,-(SP)
  414.     MOVE.W    (A6),D1
  415.     AND.W    #$0FFF,D1
  416.     LEA    mt_PeriodTable(PC),A1
  417.     MOVEQ    #0,D0
  418.     MOVEQ    #36,D2
  419. mt_ftuloop
  420.     CMP.W    (A1,D0.W),D1
  421.     BHS.S    mt_ftufound
  422.     ADDQ.L    #2,D0
  423.     DBRA    D2,mt_ftuloop
  424. mt_ftufound
  425.     MOVEQ    #0,D1
  426.     MOVE.B    n_finetune(A6),D1
  427.     MULU    #36*2,D1
  428.     ADD.L    D1,A1
  429.     MOVE.W    (A1,D0.W),n_period(A6)
  430.     MOVEM.L    (SP)+,D0-D1/A0-A1
  431.  
  432.     MOVE.W    2(A6),D0
  433.     AND.W    #$0FF0,D0
  434.     CMP.W    #$0ED0,D0 ; Notedelay
  435.     BEQ    mt_CheckMoreEfx
  436.  
  437.     MOVE.W    n_dmabit(A6),$DFF096
  438.     BTST    #2,n_wavecontrol(A6)
  439.     BNE.S    mt_vibnoc
  440.     CLR.B    n_vibratopos(A6)
  441. mt_vibnoc
  442.     BTST    #6,n_wavecontrol(A6)
  443.     BNE.S    mt_trenoc
  444.     CLR.B    n_tremolopos(A6)
  445. mt_trenoc
  446.     MOVE.L    n_start(A6),(A5)    ; Set start
  447.     MOVE.W    n_length(A6),4(A5)    ; Set length
  448.     MOVE.W    n_period(A6),D0
  449.     MOVE.W    D0,6(A5)        ; Set period
  450.     MOVE.W    n_dmabit(A6),D0
  451.     OR.W    D0,mt_DMACONtemp
  452.     BRA    mt_CheckMoreEfx
  453.  
  454. mt_SetDMA
  455.     MOVE.W    #DMAWait,D0
  456. mt_WaitDMA
  457.     DBRA    D0,mt_WaitDMA
  458.     MOVE.W    mt_DMACONtemp(PC),D0
  459.     OR.W    #$8000,D0
  460.     MOVE.W    D0,$DFF096
  461.     MOVE.W    #DMAWait,D0
  462. mt_WaitDMA2
  463.     DBRA    D0,mt_WaitDMA2
  464.  
  465.     LEA    $DFF000,A5
  466.     LEA    mt_chan4temp(PC),A6
  467.     MOVE.L    n_loopstart(A6),$D0(A5)
  468.     MOVE.W    n_replen(A6),$D4(A5)
  469.     LEA    mt_chan3temp(PC),A6
  470.     MOVE.L    n_loopstart(A6),$C0(A5)
  471.     MOVE.W    n_replen(A6),$C4(A5)
  472.     LEA    mt_chan2temp(PC),A6
  473.     MOVE.L    n_loopstart(A6),$B0(A5)
  474.     MOVE.W    n_replen(A6),$B4(A5)
  475.     LEA    mt_chan1temp(PC),A6
  476.     MOVE.L    n_loopstart(A6),$A0(A5)
  477.     MOVE.W    n_replen(A6),$A4(A5)
  478.  
  479. mt_dskip
  480.     ADD.W    #16,mt_PatternPos
  481.     MOVE.B    mt_PattDelTime,D0
  482.     BEQ.S    mt_dskc
  483.     MOVE.B    D0,mt_PattDelTime2
  484.     CLR.B    mt_PattDelTime
  485. mt_dskc    TST.B    mt_PattDelTime2
  486.     BEQ.S    mt_dska
  487.     SUBQ.B    #1,mt_PattDelTime2
  488.     BEQ.S    mt_dska
  489.     SUB.W    #16,mt_PatternPos
  490. mt_dska    TST.B    mt_PBreakFlag
  491.     BEQ.S    mt_nnpysk
  492.     SF    mt_PBreakFlag
  493.     MOVEQ    #0,D0
  494.     MOVE.B    mt_PBreakPos(PC),D0
  495.     CLR.B    mt_PBreakPos
  496.     LSL.W    #4,D0
  497.     MOVE.W    D0,mt_PatternPos
  498. mt_nnpysk
  499.     CMP.W    #1024,mt_PatternPos
  500.     BLO.S    mt_NoNewPosYet
  501. mt_NextPosition    
  502.     MOVEQ    #0,D0
  503.     MOVE.B    mt_PBreakPos(PC),D0
  504.     LSL.W    #4,D0
  505.     MOVE.W    D0,mt_PatternPos
  506.     CLR.B    mt_PBreakPos
  507.     CLR.B    mt_PosJumpFlag
  508.     ADDQ.B    #1,mt_SongPos
  509.     AND.B    #$7F,mt_SongPos
  510.     MOVE.B    mt_SongPos(PC),D1
  511.     MOVE.L    mt_SongDataPtr(PC),A0
  512.     CMP.B    950(A0),D1
  513.     BLO.S    mt_NoNewPosYet
  514.     CLR.B    mt_SongPos
  515. mt_NoNewPosYet    
  516.     TST.B    mt_PosJumpFlag
  517.     BNE.S    mt_NextPosition
  518. mt_exit    MOVEM.L    (SP)+,D0-D4/A0-A6
  519.     RTS
  520.  
  521. mt_CheckEfx
  522.     BSR    mt_UpdateFunk
  523.     MOVE.W    n_cmd(A6),D0
  524.     AND.W    #$0FFF,D0
  525.     BEQ.S    mt_PerNop
  526.     MOVE.B    n_cmd(A6),D0
  527.     AND.B    #$0F,D0
  528.     BEQ.S    mt_Arpeggio
  529.     CMP.B    #1,D0
  530.     BEQ    mt_PortaUp
  531.     CMP.B    #2,D0
  532.     BEQ    mt_PortaDown
  533.     CMP.B    #3,D0
  534.     BEQ    mt_TonePortamento
  535.     CMP.B    #4,D0
  536.     BEQ    mt_Vibrato
  537.     CMP.B    #5,D0
  538.     BEQ    mt_TonePlusVolSlide
  539.     CMP.B    #6,D0
  540.     BEQ    mt_VibratoPlusVolSlide
  541.     CMP.B    #$E,D0
  542.     BEQ    mt_E_Commands
  543. SetBack    MOVE.W    n_period(A6),6(A5)
  544.     CMP.B    #7,D0
  545.     BEQ    mt_Tremolo
  546.     CMP.B    #$A,D0
  547.     BEQ    mt_VolumeSlide
  548. mt_Return
  549.     RTS
  550.  
  551. mt_PerNop
  552.     MOVE.W    n_period(A6),6(A5)
  553.     RTS
  554.  
  555. mt_Arpeggio
  556.     MOVEQ    #0,D0
  557.     MOVE.B    mt_counter(PC),D0
  558.     DIVS    #3,D0
  559.     SWAP    D0
  560.     CMP.W    #0,D0
  561.     BEQ.S    mt_Arpeggio2
  562.     CMP.W    #2,D0
  563.     BEQ.S    mt_Arpeggio1
  564.     MOVEQ    #0,D0
  565.     MOVE.B    n_cmdlo(A6),D0
  566.     LSR.B    #4,D0
  567.     BRA.S    mt_Arpeggio3
  568.  
  569. mt_Arpeggio1
  570.     MOVEQ    #0,D0
  571.     MOVE.B    n_cmdlo(A6),D0
  572.     AND.B    #15,D0
  573.     BRA.S    mt_Arpeggio3
  574.  
  575. mt_Arpeggio2
  576.     MOVE.W    n_period(A6),D2
  577.     BRA.S    mt_Arpeggio4
  578.  
  579. mt_Arpeggio3
  580.     ASL.W    #1,D0
  581.     MOVEQ    #0,D1
  582.     MOVE.B    n_finetune(A6),D1
  583.     MULU    #36*2,D1
  584.     LEA    mt_PeriodTable(PC),A0
  585.     ADD.L    D1,A0
  586.     MOVEQ    #0,D1
  587.     MOVE.W    n_period(A6),D1
  588.     MOVEQ    #36,D3
  589. mt_arploop
  590.     MOVE.W    (A0,D0.W),D2
  591.     CMP.W    (A0),D1
  592.     BHS.S    mt_Arpeggio4
  593.     ADDQ.L    #2,A0
  594.     DBRA    D3,mt_arploop
  595.     RTS
  596.  
  597. mt_Arpeggio4
  598.     MOVE.W    D2,6(A5)
  599.     RTS
  600.  
  601. mt_FinePortaUp
  602.     TST.B    mt_counter
  603.     BNE.S    mt_Return
  604.     MOVE.B    #$0F,mt_LowMask
  605. mt_PortaUp
  606.     MOVEQ    #0,D0
  607.     MOVE.B    n_cmdlo(A6),D0
  608.     AND.B    mt_LowMask(PC),D0
  609.     MOVE.B    #$FF,mt_LowMask
  610.     SUB.W    D0,n_period(A6)
  611.     MOVE.W    n_period(A6),D0
  612.     AND.W    #$0FFF,D0
  613.     CMP.W    #113,D0
  614.     BPL.S    mt_PortaUskip
  615.     AND.W    #$F000,n_period(A6)
  616.     OR.W    #113,n_period(A6)
  617. mt_PortaUskip
  618.     MOVE.W    n_period(A6),D0
  619.     AND.W    #$0FFF,D0
  620.     MOVE.W    D0,6(A5)
  621.     RTS    
  622.  
  623. mt_FinePortaDown
  624.     TST.B    mt_counter
  625.     BNE    mt_Return
  626.     MOVE.B    #$0F,mt_LowMask
  627. mt_PortaDown
  628.     CLR.W    D0
  629.     MOVE.B    n_cmdlo(A6),D0
  630.     AND.B    mt_LowMask(PC),D0
  631.     MOVE.B    #$FF,mt_LowMask
  632.     ADD.W    D0,n_period(A6)
  633.     MOVE.W    n_period(A6),D0
  634.     AND.W    #$0FFF,D0
  635.     CMP.W    #856,D0
  636.     BMI.S    mt_PortaDskip
  637.     AND.W    #$F000,n_period(A6)
  638.     OR.W    #856,n_period(A6)
  639. mt_PortaDskip
  640.     MOVE.W    n_period(A6),D0
  641.     AND.W    #$0FFF,D0
  642.     MOVE.W    D0,6(A5)
  643.     RTS
  644.  
  645. mt_SetTonePorta
  646.     MOVE.L    A0,-(SP)
  647.     MOVE.W    (A6),D2
  648.     AND.W    #$0FFF,D2
  649.     MOVEQ    #0,D0
  650.     MOVE.B    n_finetune(A6),D0
  651.     MULU    #37*2,D0
  652.     LEA    mt_PeriodTable(PC),A0
  653.     ADD.L    D0,A0
  654.     MOVEQ    #0,D0
  655. mt_StpLoop
  656.     CMP.W    (A0,D0.W),D2
  657.     BHS.S    mt_StpFound
  658.     ADDQ.W    #2,D0
  659.     CMP.W    #37*2,D0
  660.     BLO.S    mt_StpLoop
  661.     MOVEQ    #35*2,D0
  662. mt_StpFound
  663.     MOVE.B    n_finetune(A6),D2
  664.     AND.B    #8,D2
  665.     BEQ.S    mt_StpGoss
  666.     TST.W    D0
  667.     BEQ.S    mt_StpGoss
  668.     SUBQ.W    #2,D0
  669. mt_StpGoss
  670.     MOVE.W    (A0,D0.W),D2
  671.     MOVE.L    (SP)+,A0
  672.     MOVE.W    D2,n_wantedperiod(A6)
  673.     MOVE.W    n_period(A6),D0
  674.     CLR.B    n_toneportdirec(A6)
  675.     CMP.W    D0,D2
  676.     BEQ.S    mt_ClearTonePorta
  677.     BGE    mt_Return
  678.     MOVE.B    #1,n_toneportdirec(A6)
  679.     RTS
  680.  
  681. mt_ClearTonePorta
  682.     CLR.W    n_wantedperiod(A6)
  683.     RTS
  684.  
  685. mt_TonePortamento
  686.     MOVE.B    n_cmdlo(A6),D0
  687.     BEQ.S    mt_TonePortNoChange
  688.     MOVE.B    D0,n_toneportspeed(A6)
  689.     CLR.B    n_cmdlo(A6)
  690. mt_TonePortNoChange
  691.     TST.W    n_wantedperiod(A6)
  692.     BEQ    mt_Return
  693.     MOVEQ    #0,D0
  694.     MOVE.B    n_toneportspeed(A6),D0
  695.     TST.B    n_toneportdirec(A6)
  696.     BNE.S    mt_TonePortaUp
  697. mt_TonePortaDown
  698.     ADD.W    D0,n_period(A6)
  699.     MOVE.W    n_wantedperiod(A6),D0
  700.     CMP.W    n_period(A6),D0
  701.     BGT.S    mt_TonePortaSetPer
  702.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  703.     CLR.W    n_wantedperiod(A6)
  704.     BRA.S    mt_TonePortaSetPer
  705.  
  706. mt_TonePortaUp
  707.     SUB.W    D0,n_period(A6)
  708.     MOVE.W    n_wantedperiod(A6),D0
  709.     CMP.W    n_period(A6),D0
  710.     BLT.S    mt_TonePortaSetPer
  711.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  712.     CLR.W    n_wantedperiod(A6)
  713.  
  714. mt_TonePortaSetPer
  715.     MOVE.W    n_period(A6),D2
  716.     MOVE.B    n_glissfunk(A6),D0
  717.     AND.B    #$0F,D0
  718.     BEQ.S    mt_GlissSkip
  719.     MOVEQ    #0,D0
  720.     MOVE.B    n_finetune(A6),D0
  721.     MULU    #36*2,D0
  722.     LEA    mt_PeriodTable(PC),A0
  723.     ADD.L    D0,A0
  724.     MOVEQ    #0,D0
  725. mt_GlissLoop
  726.     CMP.W    (A0,D0.W),D2
  727.     BHS.S    mt_GlissFound
  728.     ADDQ.W    #2,D0
  729.     CMP.W    #36*2,D0
  730.     BLO.S    mt_GlissLoop
  731.     MOVEQ    #35*2,D0
  732. mt_GlissFound
  733.     MOVE.W    (A0,D0.W),D2
  734. mt_GlissSkip
  735.     MOVE.W    D2,6(A5) ; Set period
  736.     RTS
  737.  
  738. mt_Vibrato
  739.     MOVE.B    n_cmdlo(A6),D0
  740.     BEQ.S    mt_Vibrato2
  741.     MOVE.B    n_vibratocmd(A6),D2
  742.     AND.B    #$0F,D0
  743.     BEQ.S    mt_vibskip
  744.     AND.B    #$F0,D2
  745.     OR.B    D0,D2
  746. mt_vibskip
  747.     MOVE.B    n_cmdlo(A6),D0
  748.     AND.B    #$F0,D0
  749.     BEQ.S    mt_vibskip2
  750.     AND.B    #$0F,D2
  751.     OR.B    D0,D2
  752. mt_vibskip2
  753.     MOVE.B    D2,n_vibratocmd(A6)
  754. mt_Vibrato2
  755.     MOVE.B    n_vibratopos(A6),D0
  756.     LEA    mt_VibratoTable(PC),A4
  757.     LSR.W    #2,D0
  758.     AND.W    #$001F,D0
  759.     MOVEQ    #0,D2
  760.     MOVE.B    n_wavecontrol(A6),D2
  761.     AND.B    #$03,D2
  762.     BEQ.S    mt_vib_sine
  763.     LSL.B    #3,D0
  764.     CMP.B    #1,D2
  765.     BEQ.S    mt_vib_rampdown
  766.     MOVE.B    #255,D2
  767.     BRA.S    mt_vib_set
  768. mt_vib_rampdown
  769.     TST.B    n_vibratopos(A6)
  770.     BPL.S    mt_vib_rampdown2
  771.     MOVE.B    #255,D2
  772.     SUB.B    D0,D2
  773.     BRA.S    mt_vib_set
  774. mt_vib_rampdown2
  775.     MOVE.B    D0,D2
  776.     BRA.S    mt_vib_set
  777. mt_vib_sine
  778.     MOVE.B    (A4,D0.W),D2
  779. mt_vib_set
  780.     MOVE.B    n_vibratocmd(A6),D0
  781.     AND.W    #15,D0
  782.     MULU    D0,D2
  783.     LSR.W    #7,D2
  784.     MOVE.W    n_period(A6),D0
  785.     TST.B    n_vibratopos(A6)
  786.     BMI.S    mt_VibratoNeg
  787.     ADD.W    D2,D0
  788.     BRA.S    mt_Vibrato3
  789. mt_VibratoNeg
  790.     SUB.W    D2,D0
  791. mt_Vibrato3
  792.     MOVE.W    D0,6(A5)
  793.     MOVE.B    n_vibratocmd(A6),D0
  794.     LSR.W    #2,D0
  795.     AND.W    #$003C,D0
  796.     ADD.B    D0,n_vibratopos(A6)
  797.     RTS
  798.  
  799. mt_TonePlusVolSlide
  800.     BSR    mt_TonePortNoChange
  801.     BRA    mt_VolumeSlide
  802.  
  803. mt_VibratoPlusVolSlide
  804.     BSR.S    mt_Vibrato2
  805.     BRA    mt_VolumeSlide
  806.  
  807. mt_Tremolo
  808.     MOVE.B    n_cmdlo(A6),D0
  809.     BEQ.S    mt_Tremolo2
  810.     MOVE.B    n_tremolocmd(A6),D2
  811.     AND.B    #$0F,D0
  812.     BEQ.S    mt_treskip
  813.     AND.B    #$F0,D2
  814.     OR.B    D0,D2
  815. mt_treskip
  816.     MOVE.B    n_cmdlo(A6),D0
  817.     AND.B    #$F0,D0
  818.     BEQ.S    mt_treskip2
  819.     AND.B    #$0F,D2
  820.     OR.B    D0,D2
  821. mt_treskip2
  822.     MOVE.B    D2,n_tremolocmd(A6)
  823. mt_Tremolo2
  824.     MOVE.B    n_tremolopos(A6),D0
  825.     LEA    mt_VibratoTable(PC),A4
  826.     LSR.W    #2,D0
  827.     AND.W    #$001F,D0
  828.     MOVEQ    #0,D2
  829.     MOVE.B    n_wavecontrol(A6),D2
  830.     LSR.B    #4,D2
  831.     AND.B    #$03,D2
  832.     BEQ.S    mt_tre_sine
  833.     LSL.B    #3,D0
  834.     CMP.B    #1,D2
  835.     BEQ.S    mt_tre_rampdown
  836.     MOVE.B    #255,D2
  837.     BRA.S    mt_tre_set
  838. mt_tre_rampdown
  839.     TST.B    n_vibratopos(A6)
  840.     BPL.S    mt_tre_rampdown2
  841.     MOVE.B    #255,D2
  842.     SUB.B    D0,D2
  843.     BRA.S    mt_tre_set
  844. mt_tre_rampdown2
  845.     MOVE.B    D0,D2
  846.     BRA.S    mt_tre_set
  847. mt_tre_sine
  848.     MOVE.B    (A4,D0.W),D2
  849. mt_tre_set
  850.     MOVE.B    n_tremolocmd(A6),D0
  851.     AND.W    #15,D0
  852.     MULU    D0,D2
  853.     LSR.W    #6,D2
  854.     MOVEQ    #0,D0
  855.     MOVE.B    n_volume(A6),D0
  856.     TST.B    n_tremolopos(A6)
  857.     BMI.S    mt_TremoloNeg
  858.     ADD.W    D2,D0
  859.     BRA.S    mt_Tremolo3
  860. mt_TremoloNeg
  861.     SUB.W    D2,D0
  862. mt_Tremolo3
  863.     BPL.S    mt_TremoloSkip
  864.     CLR.W    D0
  865. mt_TremoloSkip
  866.     CMP.W    #$40,D0
  867.     BLS.S    mt_TremoloOk
  868.     MOVE.W    #$40,D0
  869. mt_TremoloOk
  870.     MOVE.W    D0,8(A5)
  871.     MOVE.B    n_tremolocmd(A6),D0
  872.     LSR.W    #2,D0
  873.     AND.W    #$003C,D0
  874.     ADD.B    D0,n_tremolopos(A6)
  875.     RTS
  876.  
  877. mt_SampleOffset
  878.     MOVEQ    #0,D0
  879.     MOVE.B    n_cmdlo(A6),D0
  880.     BEQ.S    mt_sononew
  881.     MOVE.B    D0,n_sampleoffset(A6)
  882. mt_sononew
  883.     MOVE.B    n_sampleoffset(A6),D0
  884.     LSL.W    #7,D0
  885.     CMP.W    n_length(A6),D0
  886.     BGE.S    mt_sofskip
  887.     SUB.W    D0,n_length(A6)
  888.     LSL.W    #1,D0
  889.     ADD.L    D0,n_start(A6)
  890.     RTS
  891. mt_sofskip
  892.     MOVE.W    #$0001,n_length(A6)
  893.     RTS
  894.  
  895. mt_VolumeSlide
  896.     MOVEQ    #0,D0
  897.     MOVE.B    n_cmdlo(A6),D0
  898.     LSR.B    #4,D0
  899.     TST.B    D0
  900.     BEQ.S    mt_VolSlideDown
  901. mt_VolSlideUp
  902.     ADD.B    D0,n_volume(A6)
  903.     CMP.B    #$40,n_volume(A6)
  904.     BMI.S    mt_vsuskip
  905.     MOVE.B    #$40,n_volume(A6)
  906. mt_vsuskip
  907.     MOVE.B    n_volume(A6),D0
  908.     MOVE.W    D0,8(A5)
  909.     RTS
  910.  
  911. mt_VolSlideDown
  912.     MOVEQ    #0,D0
  913.     MOVE.B    n_cmdlo(A6),D0
  914.     AND.B    #$0F,D0
  915. mt_VolSlideDown2
  916.     SUB.B    D0,n_volume(A6)
  917.     BPL.S    mt_vsdskip
  918.     CLR.B    n_volume(A6)
  919. mt_vsdskip
  920.     MOVE.B    n_volume(A6),D0
  921.     MOVE.W    D0,8(A5)
  922.     RTS
  923.  
  924. mt_PositionJump
  925.     MOVE.B    n_cmdlo(A6),D0
  926.     SUBQ.B    #1,D0
  927.     MOVE.B    D0,mt_SongPos
  928. mt_pj2    CLR.B    mt_PBreakPos
  929.     ST     mt_PosJumpFlag
  930.     RTS
  931.  
  932. mt_VolumeChange
  933.     MOVEQ    #0,D0
  934.     MOVE.B    n_cmdlo(A6),D0
  935.     CMP.B    #$40,D0
  936.     BLS.S    mt_VolumeOk
  937.     MOVEQ    #$40,D0
  938. mt_VolumeOk
  939.     MOVE.B    D0,n_volume(A6)
  940.     MOVE.W    D0,8(A5)
  941.     RTS
  942.  
  943. mt_PatternBreak
  944.     MOVEQ    #0,D0
  945.     MOVE.B    n_cmdlo(A6),D0
  946.     MOVE.L    D0,D2
  947.     LSR.B    #4,D0
  948.     MULU    #10,D0
  949.     AND.B    #$0F,D2
  950.     ADD.B    D2,D0
  951.     CMP.B    #63,D0
  952.     BHI.S    mt_pj2
  953.     MOVE.B    D0,mt_PBreakPos
  954.     ST    mt_PosJumpFlag
  955.     RTS
  956.  
  957. mt_SetSpeed
  958.     MOVEQ    #0,D0
  959.     MOVE.B    3(A6),D0
  960.     BEQ    mt_end
  961.     CMP.B    #32,D0
  962.     BHS    SetTempo
  963.     CLR.B    mt_counter
  964.     MOVE.B    D0,mt_speed
  965.     RTS
  966.  
  967. mt_CheckMoreEfx
  968.     BSR    mt_UpdateFunk
  969.     MOVE.B    2(A6),D0
  970.     AND.B    #$0F,D0
  971.     CMP.B    #$9,D0
  972.     BEQ    mt_SampleOffset
  973.     CMP.B    #$B,D0
  974.     BEQ    mt_PositionJump
  975.     CMP.B    #$D,D0
  976.     BEQ.S    mt_PatternBreak
  977.     CMP.B    #$E,D0
  978.     BEQ.S    mt_E_Commands
  979.     CMP.B    #$F,D0
  980.     BEQ.S    mt_SetSpeed
  981.     CMP.B    #$C,D0
  982.     BEQ    mt_VolumeChange
  983.     BRA    mt_PerNop
  984.  
  985. mt_E_Commands
  986.     MOVE.B    n_cmdlo(A6),D0
  987.     AND.B    #$F0,D0
  988.     LSR.B    #4,D0
  989.     BEQ.S    mt_FilterOnOff
  990.     CMP.B    #1,D0
  991.     BEQ    mt_FinePortaUp
  992.     CMP.B    #2,D0
  993.     BEQ    mt_FinePortaDown
  994.     CMP.B    #3,D0
  995.     BEQ.S    mt_SetGlissControl
  996.     CMP.B    #4,D0
  997.     BEQ    mt_SetVibratoControl
  998.     CMP.B    #5,D0
  999.     BEQ    mt_SetFineTune
  1000.     CMP.B    #6,D0
  1001.     BEQ    mt_JumpLoop
  1002.     CMP.B    #7,D0
  1003.     BEQ    mt_SetTremoloControl
  1004.     CMP.B    #9,D0
  1005.     BEQ    mt_RetrigNote
  1006.     CMP.B    #$A,D0
  1007.     BEQ    mt_VolumeFineUp
  1008.     CMP.B    #$B,D0
  1009.     BEQ    mt_VolumeFineDown
  1010.     CMP.B    #$C,D0
  1011.     BEQ    mt_NoteCut
  1012.     CMP.B    #$D,D0
  1013.     BEQ    mt_NoteDelay
  1014.     CMP.B    #$E,D0
  1015.     BEQ    mt_PatternDelay
  1016.     CMP.B    #$F,D0
  1017.     BEQ    mt_FunkIt
  1018.     RTS
  1019.  
  1020. mt_FilterOnOff
  1021.     MOVE.B    n_cmdlo(A6),D0
  1022.     AND.B    #1,D0
  1023.     ASL.B    #1,D0
  1024.     AND.B    #$FD,$BFE001
  1025.     OR.B    D0,$BFE001
  1026.     RTS    
  1027.  
  1028. mt_SetGlissControl
  1029.     MOVE.B    n_cmdlo(A6),D0
  1030.     AND.B    #$0F,D0
  1031.     AND.B    #$F0,n_glissfunk(A6)
  1032.     OR.B    D0,n_glissfunk(A6)
  1033.     RTS
  1034.  
  1035. mt_SetVibratoControl
  1036.     MOVE.B    n_cmdlo(A6),D0
  1037.     AND.B    #$0F,D0
  1038.     AND.B    #$F0,n_wavecontrol(A6)
  1039.     OR.B    D0,n_wavecontrol(A6)
  1040.     RTS
  1041.  
  1042. mt_SetFineTune
  1043.     MOVE.B    n_cmdlo(A6),D0
  1044.     AND.B    #$0F,D0
  1045.     MOVE.B    D0,n_finetune(A6)
  1046.     RTS
  1047.  
  1048. mt_JumpLoop
  1049.     TST.B    mt_counter
  1050.     BNE    mt_Return
  1051.     MOVE.B    n_cmdlo(A6),D0
  1052.     AND.B    #$0F,D0
  1053.     BEQ.S    mt_SetLoop
  1054.     TST.B    n_loopcount(A6)
  1055.     BEQ.S    mt_jumpcnt
  1056.     SUBQ.B    #1,n_loopcount(A6)
  1057.     BEQ    mt_Return
  1058. mt_jmploop    MOVE.B    n_pattpos(A6),mt_PBreakPos
  1059.     ST    mt_PBreakFlag
  1060.     RTS
  1061.  
  1062. mt_jumpcnt
  1063.     MOVE.B    D0,n_loopcount(A6)
  1064.     BRA.S    mt_jmploop
  1065.  
  1066. mt_SetLoop
  1067.     MOVE.W    mt_PatternPos(PC),D0
  1068.     LSR.W    #4,D0
  1069.     MOVE.B    D0,n_pattpos(A6)
  1070.     RTS
  1071.  
  1072. mt_SetTremoloControl
  1073.     MOVE.B    n_cmdlo(A6),D0
  1074.     AND.B    #$0F,D0
  1075.     LSL.B    #4,D0
  1076.     AND.B    #$0F,n_wavecontrol(A6)
  1077.     OR.B    D0,n_wavecontrol(A6)
  1078.     RTS
  1079.  
  1080. mt_RetrigNote
  1081.     MOVE.L    D1,-(SP)
  1082.     MOVEQ    #0,D0
  1083.     MOVE.B    n_cmdlo(A6),D0
  1084.     AND.B    #$0F,D0
  1085.     BEQ.S    mt_rtnend
  1086.     MOVEQ    #0,D1
  1087.     MOVE.B    mt_counter(PC),D1
  1088.     BNE.S    mt_rtnskp
  1089.     MOVE.W    (A6),D1
  1090.     AND.W    #$0FFF,D1
  1091.     BNE.S    mt_rtnend
  1092.     MOVEQ    #0,D1
  1093.     MOVE.B    mt_counter(PC),D1
  1094. mt_rtnskp
  1095.     DIVU    D0,D1
  1096.     SWAP    D1
  1097.     TST.W    D1
  1098.     BNE.S    mt_rtnend
  1099. mt_DoRetrig
  1100.     MOVE.W    n_dmabit(A6),$DFF096    ; Channel DMA off
  1101.     MOVE.L    n_start(A6),(A5)    ; Set sampledata pointer
  1102.     MOVE.W    n_length(A6),4(A5)    ; Set length
  1103.     MOVE.W    #DMAWait,D0
  1104. mt_rtnloop1
  1105.     DBRA    D0,mt_rtnloop1
  1106.     MOVE.W    n_dmabit(A6),D0
  1107.     BSET    #15,D0
  1108.     MOVE.W    D0,$DFF096
  1109.     MOVE.W    #DMAWait,D0
  1110. mt_rtnloop2
  1111.     DBRA    D0,mt_rtnloop2
  1112.     MOVE.L    n_loopstart(A6),(A5)
  1113.     MOVE.L    n_replen(A6),4(A5)
  1114. mt_rtnend
  1115.     MOVE.L    (SP)+,D1
  1116.     RTS
  1117.  
  1118. mt_VolumeFineUp
  1119.     TST.B    mt_counter
  1120.     BNE    mt_Return
  1121.     MOVEQ    #0,D0
  1122.     MOVE.B    n_cmdlo(A6),D0
  1123.     AND.B    #$F,D0
  1124.     BRA    mt_VolSlideUp
  1125.  
  1126. mt_VolumeFineDown
  1127.     TST.B    mt_counter
  1128.     BNE    mt_Return
  1129.     MOVEQ    #0,D0
  1130.     MOVE.B    n_cmdlo(A6),D0
  1131.     AND.B    #$0F,D0
  1132.     BRA    mt_VolSlideDown2
  1133.  
  1134. mt_NoteCut
  1135.     MOVEQ    #0,D0
  1136.     MOVE.B    n_cmdlo(A6),D0
  1137.     AND.B    #$0F,D0
  1138.     CMP.B    mt_counter(PC),D0
  1139.     BNE    mt_Return
  1140.     CLR.B    n_volume(A6)
  1141.     MOVE.W    #0,8(A5)
  1142.     RTS
  1143.  
  1144. mt_NoteDelay
  1145.     MOVEQ    #0,D0
  1146.     MOVE.B    n_cmdlo(A6),D0
  1147.     AND.B    #$0F,D0
  1148.     CMP.B    mt_counter,D0
  1149.     BNE    mt_Return
  1150.     MOVE.W    (A6),D0
  1151.     BEQ    mt_Return
  1152.     MOVE.L    D1,-(SP)
  1153.     BRA    mt_DoRetrig
  1154.  
  1155. mt_PatternDelay
  1156.     TST.B    mt_counter
  1157.     BNE    mt_Return
  1158.     MOVEQ    #0,D0
  1159.     MOVE.B    n_cmdlo(A6),D0
  1160.     AND.B    #$0F,D0
  1161.     TST.B    mt_PattDelTime2
  1162.     BNE    mt_Return
  1163.     ADDQ.B    #1,D0
  1164.     MOVE.B    D0,mt_PattDelTime
  1165.     RTS
  1166.  
  1167. mt_FunkIt
  1168.     TST.B    mt_counter
  1169.     BNE    mt_Return
  1170.     MOVE.B    n_cmdlo(A6),D0
  1171.     AND.B    #$0F,D0
  1172.     LSL.B    #4,D0
  1173.     AND.B    #$0F,n_glissfunk(A6)
  1174.     OR.B    D0,n_glissfunk(A6)
  1175.     TST.B    D0
  1176.     BEQ    mt_Return
  1177. mt_UpdateFunk
  1178.     MOVEM.L    A0/D1,-(SP)
  1179.     MOVEQ    #0,D0
  1180.     MOVE.B    n_glissfunk(A6),D0
  1181.     LSR.B    #4,D0
  1182.     BEQ.S    mt_funkend
  1183.     LEA    mt_FunkTable(PC),A0
  1184.     MOVE.B    (A0,D0.W),D0
  1185.     ADD.B    D0,n_funkoffset(A6)
  1186.     BTST    #7,n_funkoffset(A6)
  1187.     BEQ.S    mt_funkend
  1188.     CLR.B    n_funkoffset(A6)
  1189.  
  1190.     MOVE.L    n_loopstart(A6),D0
  1191.     MOVEQ    #0,D1
  1192.     MOVE.W    n_replen(A6),D1
  1193.     ADD.L    D1,D0
  1194.     ADD.L    D1,D0
  1195.     MOVE.L    n_wavestart(A6),A0
  1196.     ADDQ.L    #1,A0
  1197.     CMP.L    D0,A0
  1198.     BLO.S    mt_funkok
  1199.     MOVE.L    n_loopstart(A6),A0
  1200. mt_funkok
  1201.     MOVE.L    A0,n_wavestart(A6)
  1202.     MOVEQ    #-1,D0
  1203.     SUB.B    (A0),D0
  1204.     MOVE.B    D0,(A0)
  1205. mt_funkend
  1206.     MOVEM.L    (SP)+,A0/D1
  1207.     RTS
  1208.  
  1209.  
  1210. mt_FunkTable dc.b 0,5,6,7,8,10,11,13,16,19,22,26,32,43,64,128
  1211.  
  1212. mt_VibratoTable    
  1213.     dc.b   0, 24, 49, 74, 97,120,141,161
  1214.     dc.b 180,197,212,224,235,244,250,253
  1215.     dc.b 255,253,250,244,235,224,212,197
  1216.     dc.b 180,161,141,120, 97, 74, 49, 24
  1217.  
  1218. mt_PeriodTable
  1219. ; Tuning 0, Normal
  1220.     dc.w    856,808,762,720,678,640,604,570,538,508,480,453
  1221.     dc.w    428,404,381,360,339,320,302,285,269,254,240,226
  1222.     dc.w    214,202,190,180,170,160,151,143,135,127,120,113
  1223. ; Tuning 1
  1224.     dc.w    850,802,757,715,674,637,601,567,535,505,477,450
  1225.     dc.w    425,401,379,357,337,318,300,284,268,253,239,225
  1226.     dc.w    213,201,189,179,169,159,150,142,134,126,119,113
  1227. ; Tuning 2
  1228.     dc.w    844,796,752,709,670,632,597,563,532,502,474,447
  1229.     dc.w    422,398,376,355,335,316,298,282,266,251,237,224
  1230.     dc.w    211,199,188,177,167,158,149,141,133,125,118,112
  1231. ; Tuning 3
  1232.     dc.w    838,791,746,704,665,628,592,559,528,498,470,444
  1233.     dc.w    419,395,373,352,332,314,296,280,264,249,235,222
  1234.     dc.w    209,198,187,176,166,157,148,140,132,125,118,111
  1235. ; Tuning 4
  1236.     dc.w    832,785,741,699,660,623,588,555,524,495,467,441
  1237.     dc.w    416,392,370,350,330,312,294,278,262,247,233,220
  1238.     dc.w    208,196,185,175,165,156,147,139,131,124,117,110
  1239. ; Tuning 5
  1240.     dc.w    826,779,736,694,655,619,584,551,520,491,463,437
  1241.     dc.w    413,390,368,347,328,309,292,276,260,245,232,219
  1242.     dc.w    206,195,184,174,164,155,146,138,130,123,116,109
  1243. ; Tuning 6
  1244.     dc.w    820,774,730,689,651,614,580,547,516,487,460,434
  1245.     dc.w    410,387,365,345,325,307,290,274,258,244,230,217
  1246.     dc.w    205,193,183,172,163,154,145,137,129,122,115,109
  1247. ; Tuning 7
  1248.     dc.w    814,768,725,684,646,610,575,543,513,484,457,431
  1249.     dc.w    407,384,363,342,323,305,288,272,256,242,228,216
  1250.     dc.w    204,192,181,171,161,152,144,136,128,121,114,108
  1251. ; Tuning -8
  1252.     dc.w    907,856,808,762,720,678,640,604,570,538,508,480
  1253.     dc.w    453,428,404,381,360,339,320,302,285,269,254,240
  1254.     dc.w    226,214,202,190,180,170,160,151,143,135,127,120
  1255. ; Tuning -7
  1256.     dc.w    900,850,802,757,715,675,636,601,567,535,505,477
  1257.     dc.w    450,425,401,379,357,337,318,300,284,268,253,238
  1258.     dc.w    225,212,200,189,179,169,159,150,142,134,126,119
  1259. ; Tuning -6
  1260.     dc.w    894,844,796,752,709,670,632,597,563,532,502,474
  1261.     dc.w    447,422,398,376,355,335,316,298,282,266,251,237
  1262.     dc.w    223,211,199,188,177,167,158,149,141,133,125,118
  1263. ; Tuning -5
  1264.     dc.w    887,838,791,746,704,665,628,592,559,528,498,470
  1265.     dc.w    444,419,395,373,352,332,314,296,280,264,249,235
  1266.     dc.w    222,209,198,187,176,166,157,148,140,132,125,118
  1267. ; Tuning -4
  1268.     dc.w    881,832,785,741,699,660,623,588,555,524,494,467
  1269.     dc.w    441,416,392,370,350,330,312,294,278,262,247,233
  1270.     dc.w    220,208,196,185,175,165,156,147,139,131,123,117
  1271. ; Tuning -3
  1272.     dc.w    875,826,779,736,694,655,619,584,551,520,491,463
  1273.     dc.w    437,413,390,368,347,328,309,292,276,260,245,232
  1274.     dc.w    219,206,195,184,174,164,155,146,138,130,123,116
  1275. ; Tuning -2
  1276.     dc.w    868,820,774,730,689,651,614,580,547,516,487,460
  1277.     dc.w    434,410,387,365,345,325,307,290,274,258,244,230
  1278.     dc.w    217,205,193,183,172,163,154,145,137,129,122,115
  1279. ; Tuning -1
  1280.     dc.w    862,814,768,725,684,646,610,575,543,513,484,457
  1281.     dc.w    431,407,384,363,342,323,305,288,272,256,242,228
  1282.     dc.w    216,203,192,181,171,161,152,144,136,128,121,114
  1283.  
  1284. mt_chan1temp    dc.l    0,0,0,0,0,$00010000,0,  0,0,0,0
  1285. mt_chan2temp    dc.l    0,0,0,0,0,$00020000,0,  0,0,0,0
  1286. mt_chan3temp    dc.l    0,0,0,0,0,$00040000,0,  0,0,0,0
  1287. mt_chan4temp    dc.l    0,0,0,0,0,$00080000,0,  0,0,0,0
  1288.  
  1289. mt_SampleStarts    dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1290.         dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1291.  
  1292. mt_SongDataPtr    dc.l 0
  1293. mt_speed    dc.b 6
  1294. mt_counter    dc.b 0
  1295. mt_SongPos    dc.b 0
  1296. mt_PBreakPos    dc.b 0
  1297. mt_PosJumpFlag    dc.b 0
  1298. mt_PBreakFlag    dc.b 0
  1299. mt_LowMask    dc.b 0
  1300. mt_PattDelTime    dc.b 0
  1301. mt_PattDelTime2    dc.b 0
  1302. mt_Enable    dc.b 0
  1303. mt_PatternPos    dc.w 0
  1304. mt_DMACONtemp    dc.w 0
  1305.  
  1306.         section  mod,data_c
  1307.  
  1308. mt_data        incbin "st-00:modules/mod.occ-san-geen plus"
  1309.  
  1310. ;/* End of File */
  1311.